2 LET P=0
3 LET Q=0
6 PRINT "DO YOU WANT INSTRUCTIONS"
7 IF INKEY$="" THEN GOTO 7
8 IF INKEY$="Y" THEN GOSUB 585
9 CLS
10 LET B=(RND>.5)-(RND<.5)
15 IF B=0 THEN GOTO 10
20 LET A=INT(RND*23)+2
25 LET E=0
40 LET S=0
50 LET T=INT(RND*28)
60 PRINT AT 8,6;"INPUT DIFFICULTY."
70 PRINT AT 10,8;" 1=HARD"
80 PRINT AT 11,8;" 2=MEDIUM"
90 PRINT AT 12,8;" 3=EASY"
100 IF Q>0 THEN PRINT AT 14,0;"IF YOU WANT YOUR SCORE AND RATING THEN PRESS 0."
110 IF INKEY$="" THEN GOTO 110
120 IF INKEY$="0" THEN GOTO 450
130 IF INKEY$="1" THEN LET I=0.25
140 IF INKEY$="2" THEN LET I=0.5
150 IF INKEY$="3" THEN LET I=1
160 FAST
170 CLS
180 FOR U=1 TO 50
190 LET U1=INT(RND*31)
200 LET U2=INT(RND*17)
210 PRINT AT U2,U1;"."
220 NEXT U
230 PRINT AT 21,0;"\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~\~~"
240 SLOW
250 LET B=(A=2)-(A=25)+B*(A>2 AND A<25)
260 LET A=A+B
270 LET T=T+(INKEY$="0")-(INKEY$="1")
280 LET T=T+(T=0)-(T=28)
290 PRINT AT S,T;"<\''>"
300 PRINT AT 20,A;" \;;\;;\;;\'. "
310 PRINT AT 20,0;"   "
320 LET S=S+1
330 IF S=20 THEN GOTO 350
340 GOTO 250
350 IF T=A+2 THEN GOTO 380
360 PRINT AT 5,5;"YOU HAVE CRASHED"
370 GOTO 400
380 PRINT AT 5,7;"SAFE LANDING"
390 LET P=P+1
400 LET Q=Q+1
410 IF Q=10 THEN GOTO 450
420 PRINT AT S,T;"<\''>"
425 PAUSE 200
430 CLS
440 GOTO 20
450 CLS
460 PRINT "YOU LANDED SAFELY ";P;" TIMES OUT OF ";Q
470 LET W=(P/Q)*10
480 IF W=10 THEN LET D$="SUPREME COMMANDER OF THE WORLD     PILOTS ASSOCIATION"
490 IF W>7 AND W<10 THEN LET D$="SUPREME AIR FLEET COMMANDER"
500 IF W>5 AND W<8 THEN LET D$="PROFESSIONAL AIRCRAFT LANDER"
510 IF W>3 AND W<6 THEN LET D$="AMATEUR  AIRCRAFT LANDER"
520 IF W>1 AND W<4 THEN LET D$="I AM GLAD THIS IS ONLY A COMPUTER SIMULATION"
530 IF W<2 THEN LET D$="DANGEROUS UNCOORDINATED IDIOT"
535 IF W>1 AND W<4 THEN PRINTD$
540 IF W>1 AND W<4 THEN GOTO 560
550 PRINT "YOUR RATING IS     :-";D$
560 PRINT AT 8,6;"ANOTHER GO?"
570 IF INKEY$=""THEN GOTO 570
580 RUN
585 CLS
590 PRINT AT 1,8;"COSMOS LANDING"
610 PRINT AT 3,0;"YOU ARE IN CHARGE OF THE STARSHIP ASTRON";
611 PRINT"YOU HAVE JUST SUCCESSFULLY COMPLETED YOUR MISSION IN THE OUTER";
620 PRINT"LIMITS OF THE GALAXY"
630 PRINT AT 6,0;"HAVING ALREADY LANDED SAFELY YOURSELF YOU MUST LAND YOUR ";
640 PRINT"RADIO CONTROLLED DRONES ONTO THE CONSTANTLY MOVING LANDING"
650 PRINT"PLATFORM"
660 PRINT"TO OPERATE THE RADIO SIGNAL PRESS 1 FOR"
665 PRINT" LEFT AND 0 FOR RIGHT"
670 PRINT" THERE ARE THREE DIFFERENT LANDING SPEEDS"
680 PRINT" DEPENDING ON HOW SKILLED YOU ARE"
690 PRINT"YOU HAVE TEN DRONES TO LAND"
710 PAUSE 40000
720 RETURN